Exercícios de Lógica de Programação (10 Algoritmos)

1. Contagem de Valores Maiores que 10

Implemente um algoritmo que receba 100 valores e conte o número de ocorrências de valores maiores do que 10.

algoritmo "Questão 1"
var
  c, i, x : inteiro
inicio
  c <- 0
  Para i de 1 ate 100 faca
    Escreva("Digite um valor:")
    Leia(x)
    Se x > 10 Entao
      c <- c + 1
    FimSe
  FimPara
  Escreva("Número de elementos maiores do que 10:", c)
fimalgoritmo

2. Soma de Valores Menores que 100

Implemente um algoritmo que receba 200 valores e calcule a soma entre os elementos que forem menores do que 100.

algoritmo "Questão 2"
var
  s, i, x : inteiro
inicio
  s <- 0
  Para i de 1 ate 200 faca
    Escreva("Digite um valor:")
    Leia(x)
    Se x < 100 Entao
      s <- s + x
    FimSe
  FimPara
  Escreva("Soma dos elementos menores do que 100:", s)
fimalgoritmo

3. Multiplicação de Valores Entre 10 e 20

Implemente um algoritmo que receba 10 valores e calcule a multiplicação entre os valores que forem maiores do que 10 e menores do que 20.

algoritmo "Questão 3"
var
  i : inteiro
  p, x : real
inicio
  p <- 1
  Para i de 1 ate 10 faca
    Escreva("Digite um valor:")
    Leia(x)
    Se (x > 10) e (x < 20) Entao
      p <- p * x
    FimSe
  FimPara
  Escreva("Multiplicação entre os elementos entre 10 e 20:", p)
fimalgoritmo

4. Média Aritmética de Valores Pares

Implemente um algoritmo que receba 200 valores e calcule a média aritmética entre todos os elementos que forem pares.

algoritmo "Questão 4"
var
  x, s, i, c : inteiro
inicio
  s <- 0
  c <- 0
  Para i de 1 ate 200 faca
    Escreva("Digite um valor:")
    Leia(x)
    Se x mod 2 = 0 Entao
      s <- s + x
      c <- c + 1
    FimSe
  FimPara
  Se c > 0 Entao
    Escreva("Média aritmética dos valores pares:", s / c)
  Senao
    Escreva("Nada a calcular")
  FimSe
fimalgoritmo

5. Percentual de Valores Negativos

Implemente um algoritmo que receba 100 valores e calcule o percentual entre os valores que forem negativos.

algoritmo "Questão 5"
var
  x, i, c : inteiro
inicio
  c <- 0
  Para i de 1 ate 100 faca
    Escreva("Digite um valor:")
    Leia(x)
    Se x < 0 Entao
      c <- c + 1
    FimSe
  FimPara
  Escreva("Percentual de valores negativos:", c, "%")
fimalgoritmo

6. Média de Valores Ímpares e Menores que 100

Implemente um algoritmo que receba um número indefinido de valores e calcule a média aritmética entre os valores que forem ímpares e menores do que 100.

algoritmo "Questão 6"
var
  x, c, s : inteiro
  resposta : caractere
inicio
  c <- 0
  s <- 0
  resposta <- "s"
  Enquanto resposta = "s" faca
    Escreva("Digite um valor:")
    Leia(x)
    Se (x mod 2 <> 0) e (x < 100) Entao
      s <- s + x
      c <- c + 1
    FimSe
    Escreva("Deseja fornecer mais algum valor (s/n)?")
    Leia(resposta)
  FimEnquanto
  Se c > 0 Entao
    Escreva("Média aritmética entre os valores ímpares e menores do que 100:", s / c)
  Senao
    Escreva("Nada a calcular")
  FimSe
fimalgoritmo

7. Percentual de Valores Pares Entre 20 e 50

Implemente um algoritmo que receba um número indefinido de valores e calcule o percentual entre os valores que forem pares e estiverem dentro do intervalo de 20 e 50.

algoritmo "Questão 7"
var
  x, c, ct : inteiro
  resposta : caractere
inicio
  c <- 0
  ct <- 0
  resposta <- "s"
  Enquanto resposta = "s" faca
    Escreva("Digite um valor:")
    Leia(x)
    Se (x mod 2 = 0) e (x > 20) e (x < 50) Entao
      c <- c + 1
    FimSe
    ct <- ct + 1
    Escreva("Deseja fornecer mais algum valor (s/n)?")
    Leia(resposta)
  FimEnquanto
  Escreva("Percentual de valores pares entre 20 e 50:", c * 100 / ct, "%")
fimalgoritmo

8. Encontrar o Maior Valor

Implemente um algoritmo que receba um número indefinido de valores e encontre o maior entre todos os elementos.

algoritmo "Questão 8"
var
  x, maior, primeiro : inteiro
  resposta : caractere
inicio
  primeiro <- 1
  resposta <- "s"
  Enquanto resposta = "s" faca
    Escreva("Digite um valor:")
    Leia(x)
    Se primeiro = 1 Entao
      maior <- x
      primeiro <- 0
    Senao
      Se x > maior Entao
        maior <- x
      FimSe
    FimSe
    Escreva("Deseja fornecer mais algum valor (s/n)?")
    Leia(resposta)
  FimEnquanto
  Escreva("Maior de todos os elementos digitados:", maior)
fimalgoritmo

9. Verificar se é Número Primo

Implemente um algoritmo que receba um número e verifique e informe se é um número primo.

algoritmo "Questão 9"
var
  x, c, i : inteiro
inicio
  Escreva("Digite um valor:")
  Leia(x)
  c <- 0
  Para i de 1 ate x Faca
    Se x mod i = 0 Entao
      c <- c + 1
    FimSe
  FimPara
  Se c = 2 Entao
    Escreval("Valor é um número primo!")
  Senao
    Escreval("Valor NÃO é um número primo!")
  FimSe
fimalgoritmo

10. Informar Números Primos Fornecidos

Implemente um algoritmo que receba um número indefinido de valores e informe sempre que um número primo for fornecido.

algoritmo "Questão 10"
var
  x, c, i : inteiro
  resposta : caractere
inicio
  resposta <- "s"
  Enquanto resposta = "s" faca
    Escreva("Digite um valor:")
    Leia(x)
    c <- 0
    Para i de 1 ate x Faca
      Se x mod i = 0 Entao
        c <- c + 1
      FimSe
    FimPara
    Se c = 2 Entao
      Escreval("Valor é um número primo!")
    Senao
      Escreval("Valor NÃO é um número primo!")
    FimSe
    Escreva("Deseja fornecer mais algum valor (s/n)?")
    Leia(resposta)
  FimEnquanto
fimalgoritmo