Exercícios de Lógica de Programação em Portugol (L.A.)

Exercícios de Lógica de Programação (L.A.)

Implemente os seguintes algoritmos em L.A.:

1. Algoritmo que liste os números pares até 1000.
2. Algoritmo que liste os múltiplos de 7 até 1000.
3. Algoritmo que receba dois valores e liste os números inteiros existentes entre eles.
4. Algoritmo que receba um valor e liste os múltiplos deste valor até 10000.
5. Algoritmo que receba o primeiro termo e a razão de uma P.A. e liste seus 30 primeiros termos.
6. Algoritmo que receba um valor e liste todos os seus divisores.
7. Algoritmo que gere os valores inteiros de X de 1 a 100 e mostre os valores de Y para a equação: Y = 3X + 7.
8. Algoritmo que liste, com saltos negativos de quatro unidades, os números a partir de 100 até o valor mais próximo de -100.
9. Algoritmo que receba 1000 valores e encontre o maior elemento.
10. Algoritmo que receba três valores e calcule o M.D.C. entre eles.

Resoluções

algoritmo "Questão 1"
var x : Inteiro
inicio
  x <- 2
  Enquanto x <= 1000 Faca
    Escreva(x, " ")
    x <- x + 2
  FimEnquanto
fimalgoritmo

algoritmo "Questão 2"
var x : Inteiro
inicio
  x <- 7
  Enquanto x <= 1000 Faca
    Escreva(x, " ")
    x <- x + 7
  FimEnquanto
fimalgoritmo

algoritmo "Questão 3"
var x, y, i : Inteiro
inicio
  Escreva("Digite dois valores:")
  Leia(x, y)
  Se x <= y Entao
    Para i de x ate y faca Escreva(i, " ") FimPara
  Senao
    Para i de y ate x faca Escreva(i, " ") FimPara
  FimSe
fimalgoritmo

algoritmo "Questão 4"
var x, y : Inteiro
inicio
  Escreva("Digite um valor:")
  Leia(x)
  y <- x
  Enquanto y <= 10000 faca
    Escreva(y, " ")
    y <- y + x
  FimEnquanto
fimalgoritmo

algoritmo "Questão 5"
var a, r : Real
    i : inteiro
inicio
  Escreva("Digite o primeiro termo e a razão:")
  Leia(a, r)
  Para i de 1 ate 30 Faca
    Escreva(a, " ")
    a <- a + r
  FimPara
fimalgoritmo

algoritmo "Questão 6"
var x, i : inteiro
inicio
  Escreva("Digite um valor:")
  Leia(x)
  Para i de 1 ate x Faca
    Se x mod i = 0 Entao Escreva(i, " ") FimSe
  FimPara
fimalgoritmo

algoritmo "Questão 7"
var x : inteiro
inicio
  Para x de 1 ate 100 Faca
    Escreval("X = ", x, " - Y = ", 3 * x + 7)
  FimPara
fimalgoritmo

algoritmo "Questão 8"
var x : inteiro
inicio
  x <- 100
  Enquanto x >= -100 faca
    Escreval(x)
    x <- x - 4
  FimEnquanto
fimalgoritmo

algoritmo "Questão 9"
var x, primeiro, maior, i : inteiro
inicio
  primeiro <- 1
  Para i de 1 ate 100 faca
    Escreva("Entre com um valor:")
    Leia(x)
    Se primeiro = 1 Entao
      maior <- x
      primeiro <- 0
    Senao
      Se x > maior Entao maior <- x FimSe
    FimSe
  FimPara
  Escreva("Maior:", maior)
fimalgoritmo

algoritmo "Questão 10"
var a, b, c, i, mdc : inteiro
inicio
  Escreva("Digite três valores:")
  Leia(a, b, c)
  Para i de 1 ate a faca
    Se (a mod i = 0) e (b mod i = 0) e (c mod i = 0) Entao
      mdc <- i
    FimSe
  FimPara
  Escreva("MDC:", mdc)
fimalgoritmo